{
[@微信验证脚本QQ136930629]

#if
checknamelist ..\QuestDiary\微信验证脚本QQ136930629\解除微信绑定人物.txt
#act
delnamelist ..\QuestDiary\微信验证脚本QQ136930629\解除微信绑定人物.txt
mov T0

#IF
not equal <$STR(T1)> <$MACHINEID>
not equal <$STR(T0)>
#Act
goto @验证检测安全区
set [188] 1 (给予标识,别让按钮把装备回收了)
BREAK

#IF
check [188] 1
not equal <$STR(T0)>
#ACT
;异地登录过一次,每次强制验证
goto @验证检测安全区
BREAK

#IF
equal <$STR(T0)>
#Act
DELAYGOTO 10 @绑定微信界面
break

[@验证检测安全区]
#IF
check [188] 0
#Act
;模板消息 推送功能   写入文本，服务号并且认真可以使用该功能，参数一：模板ID  参数二：微信ID 后面参数根据模板ID中的格式写入
ADDTEXTLIST ..\QuestDiary\微信验证脚本QQ136930629\推送模板消息.txt JqHDk6GoJPnbOYGmXN4dFQPaI0N78xQme94-jnO0dfo|<$STR(T0)>|您的账号在异地登陆!|<$SERVERNAME>|<$USERNAME>|<$USERID>|温馨提示：请检查帐号安全情况。

#IF
NOT INSAFEZONE
#ACT
GoHome
DELAYGOTO 10 @验证微信界面
#ELSEACT
DELAYGOTO 10 @验证微信界面


[@绑定微信界面]
#IF
equal <$STR(T0)>
#Act
CloseBigDialogBox
#SAY
<Img:1570:9:-10:0>
　　　　<【绑定微信】/FCOLOR=243>
\ \　　　　　　　　　　　　　<为了您的账号安全,请绑定微信!/FCOLOR=250>
\ \　　　　　　　　　　　　　<绑定微信可以有效避免账号被盗!/FCOLOR=253>
\ \　　　　　　　　　　　　　<关注微信公众号 /FCOLOR=249><发送"１"获取验证码/FCOLOR=250>
\ \                          <输入微信"验证码"绑定微信/@@InPutInteger20>   <扫描微信二维码快速绑定/@使用微信二维码直接绑定>


#ELSESAY
<Img:1570:9:-10:0>
　　　　　<【解绑微信】/FCOLOR=243>
\ \　　　　　　　　　　　　　<解除绑定将会影响到您的账号安全!/FCOLOR=250>
\ \　　　　　　　　　　　　　<绑定微信可以有效避免账号被盗!/FCOLOR=253>
\ \　　　　　　　　　　　　　<关注微信公众号 /FCOLOR=249><发送"１"获取验证码/FCOLOR=250>
\ \                           <输入微信"验证码"解绑微信/@@InPutInteger21>   <扫描微信二维码快速解绑/@使用微信二维码直接解绑>

[@验证微信界面]
#IF
#Act
CloseBigDialogBox
;此处给予无敌。隐身。锁定。防止活动 按钮传送出去
ChangeModeEx 10 65000
ChangeModeEx 2 65000
ChangeModeEx 1 65000
Gmexecute Shutup Self 88888 (禁言88888分钟)
sendmsg 6 防止捣乱,未验证微信用户禁止发言。
#SAY
<Img:1570:9:-10:0>
　　　　<【验证微信】/FCOLOR=243>
\ \　　　　　　　　　　　　　<检测到您的电脑登陆异常!/FCOLOR=250>
\ \　　　　　　　　　　　　　<请您配合解绑微信!/FCOLOR=253>
\ \　　　　　　　　　　　　　<关注微信公众号 /FCOLOR=249><发送"１"获取验证码/FCOLOR=250>
\ \                           <输入微信"验证码"验证微信/@@InPutInteger22>   <扫描微信二维码快速验证/@使用微信二维码直接验证>


[@InPutInteger20]
#IF
not equal <$STR(T0)>
#ACT
MESSAGEBOX 您已绑定微信,无需重复绑定！
BREAK
#ELSEACT
mov s$微信抽取验证码 <$STR(N20)>
goto @抽取验证调用


#IF 
equal <$STR(S$微信ID)>
#ACT
MessageBox 您输入的验证码不正确！
BREAK
#ELSEACT
mov T0 <$STR(S$微信ID)>
Mov T1 <$MACHINEID>
sendmsg 6 ═══════
sendmsg 6 绑定微信成功。
sendmsg 6 绑定微信成功。
sendmsg 6 绑定微信成功。
sendmsg 6 ═══════
close


[@InPutInteger21]
#IF
equal <$STR(T0)>
#ACT
MESSAGEBOX 没有绑定微信！
BREAK
#ELSEACT
mov s$微信抽取验证码 <$STR(N21)>
goto @抽取验证调用

#IF
EQUAL <$STR(S$微信ID)>
#ACT
MessageBox 您输入的验证码不正确！
BREAK

#IF
EQUAL <$STR(S$微信ID)> <$STR(T0)>
#ACT
Mov T1 <$MACHINEID>
Mov T0 
sendmsg 6 ═════════
sendmsg 6 解除微信绑定成功。
sendmsg 6 解除微信绑定成功。
sendmsg 6 解除微信绑定成功。
sendmsg 6 ═════════
close
#ELSEACT
MessageBox 您与绑定的微信ID不符！


[@InPutInteger22]
#IF
equal <$STR(T0)>
#ACT
MESSAGEBOX 没有绑定微信！
BREAK
#ELSEACT
mov s$微信抽取验证码 <$STR(N22)>
goto @抽取验证调用

#IF
EQUAL <$STR(S$微信ID)>
#ACT
MessageBox 您输入的验证码不正确！
BREAK

#IF
EQUAL <$STR(S$微信ID)> <$STR(T0)>
#ACT
Mov T1 <$MACHINEID>
;解除无敌。隐身。锁定状态,解除标识
set [188] 0
ChangeModeEx 10 1
ChangeModeEx 2 1
ChangeModeEx 1 1
sendmsg 6 ═══════
sendmsg 6 验证微信成功。
sendmsg 6 验证微信成功。
sendmsg 6 验证微信成功。
sendmsg 6 ═══════
close
BREAK
#ELSEACT
MessageBox 您与绑定的微信ID不符！


;------------------微信生成动态二维码，微信扫码功能--------------------------------------

[@使用微信二维码直接绑定]
#Act
CLOSE
MOV S$微信二维码信息 服务器：<$SERVERNAME>|账号：<$USERID>|角色：<$USERNAME>|绑定微信,请在游戏中点击确定
goto @开始生成二维码

[@使用微信二维码直接验证]
#Act
CLOSE
MOV S$微信二维码信息 服务器：<$SERVERNAME>|账号：<$USERID>|角色：<$USERNAME>|验证微信,请在游戏中点击确定
goto @开始生成二维码

[@使用微信二维码直接解绑]
#Act
CLOSE
;
MOV S$微信二维码信息 服务器：<$SERVERNAME>|账号：<$USERID>|角色：<$USERNAME>|解绑微信,请在游戏中点击确定
goto @开始生成二维码

[@开始生成二维码]
#ACT
MOV S$二维码地址 <$YEAR>-<$MONTH>-<$DAY>-<$HOUR>-<$MINUTE>-<$SECOND>
MOVR N$二维码地址 0 10
INC S$二维码地址 <$STR(N$二维码地址)>
MOVR N$二维码地址 0 10
INC S$二维码地址 <$STR(N$二维码地址)>
MOVR N$二维码地址 0 10
INC S$二维码地址 <$STR(N$二维码地址)>
MOVR N$二维码地址 0 10
INC S$二维码地址 <$STR(N$二维码地址)>
;<$STR(S$二维码地址)>|是必须的
ADDTEXTLIST ..\QuestDiary\微信验证脚本QQ136930629\微信二维码申请.txt <$STR(S$二维码地址)>|<$STR(S$微信二维码信息)>
DelayCall 1000 @微信弹出二维码
SHOWPROGRESSBARDLG 1 @exit 正在生成二维码,进度%d%... 0

[@微信弹出二维码]
#IF
#ACT
;打开网页微信二维码，服务器IP(可以域名)+网关开放的端口.
WebBrowser http://127.0.0.1:5888/?&dh=<$STR(S$二维码地址)>
MessageBox 确定已扫描微信二维码 @确定扫描微信二维码 @exit

[@确定扫描微信二维码]
#IF
#ACT
mov s$微信抽取验证码 <$STR(S$二维码地址)>
goto @抽取验证调用
#IF
EQUAL <$STR(S$微信ID)>
#ACT
MessageBox 未收到扫码信息。
break

#IF
checkcontainstext <$STR(S$验证码备注)> |绑定微信
#ACT
mov T0 <$STR(S$微信ID)>
Mov T1 <$MACHINEID>
sendmsg 6 ═══════
sendmsg 6 绑定微信成功。
sendmsg 6 绑定微信成功。
sendmsg 6 绑定微信成功。
sendmsg 6 ═══════
close
break

#IF
checkcontainstext <$STR(S$验证码备注)> |解绑微信
EQUAL <$STR(S$微信ID)> <$STR(T0)>
#ACT
Mov T0 
Mov T1 <$MACHINEID>
sendmsg 6 ═════════
sendmsg 6 解除微信绑定成功。
sendmsg 6 解除微信绑定成功。
sendmsg 6 解除微信绑定成功。
sendmsg 6 ═════════
close
break

#IF
checkcontainstext <$STR(S$验证码备注)> |验证微信
EQUAL <$STR(S$微信ID)> <$STR(T0)>
#ACT
Mov T1 <$MACHINEID>
;解除无敌。隐身。锁定状态,解除标识
set [188] 0
ChangeModeEx 10 1
ChangeModeEx 2 1
ChangeModeEx 1 1
sendmsg 6 ═══════
sendmsg 6 验证微信成功。
sendmsg 6 验证微信成功。
sendmsg 6 验证微信成功。
sendmsg 6 ═══════
close
BREAK

#IF
NOT EQUAL <$STR(S$微信ID)> <$STR(T0)>
#ACT
MessageBox 扫描二维码的微信ID与您的绑定的微信ID不符.
#ELSEACT
MessageBox 二维码判断信息未找到,请联系技术修改脚本.
BREAK


[@抽取验证调用]
#IF
#ACT
mov S$微信ID 
MOV S$验证码备注 
MOV S$公众号ID 

#IF
CHECKTEXTLIST ..\QuestDiary\微信验证脚本QQ136930629\验证码.txt <$STR(s$微信抽取验证码)>
#ACT
DelTextList ..\QuestDiary\微信验证脚本QQ136930629\验证码.txt <$STR(s$微信抽取验证码)>
Getliststring ..\QuestDiary\微信验证脚本QQ136930629\处理目录QQ136930629\<$STR(s$微信抽取验证码)>.txt 0 S$微信ID
Getliststring ..\QuestDiary\微信验证脚本QQ136930629\处理目录QQ136930629\<$STR(s$微信抽取验证码)>.txt 1 S$验证码备注
Getliststring ..\QuestDiary\微信验证脚本QQ136930629\处理目录QQ136930629\<$STR(s$微信抽取验证码)>.txt 2 S$公众号ID
BREAK


}